摘要：很多公司的微控制器集成了LCD顯示屏控制器，它采用硬件實(shí)現(xiàn)。有的微控制器，例如DS89C450，不提供這一功能，但是可以通過軟件實(shí)現(xiàn)一個(gè)簡單的顯示控制器。本應(yīng)用筆記闡述怎樣利用DS89C450超高速快閃微控制器來驅(qū)動(dòng)7段數(shù)位靜態(tài)LCD顯示板。

簡介

液晶顯示屏(LCD)廣泛用于各種現(xiàn)代電子設(shè)備上，例如計(jì)算器、手持式血糖儀、氣站泵和電視機(jī)等。LCD功耗低，直視時(shí)有清晰的顯示，在很多應(yīng)用中已經(jīng)替代了老的LED顯示屏。很多微控制器(例如MAXQ2000)集成了能夠驅(qū)動(dòng)LCD顯示板的LCD控制器，其占空比高達(dá)?。但是在某些情況下，具體應(yīng)用中理想的微控制器不一定集成LCD控制器。在這些情況下，可以使用微控制器的端口引腳來驅(qū)動(dòng)顯示器，在軟件中實(shí)現(xiàn)顯示控制器。

本應(yīng)用筆記闡述怎樣利用DS89C450超高速快閃微控制器來實(shí)現(xiàn)一個(gè)簡單的7段數(shù)位靜態(tài)LCD顯示控制器。由于沒有采用DS89C450的特殊功能，該實(shí)例代碼可以很容易導(dǎo)出到任何8051兼容微控制器中，只要微控制器有足夠的引腳來驅(qū)動(dòng)本應(yīng)用中所采用的LCD顯示板。

可以下載(ASM)本應(yīng)用筆記的實(shí)例代碼。

選擇一款LCD顯示板

在應(yīng)用中選擇LCD顯示板時(shí)，應(yīng)該為LCD仔細(xì)挑選匹配的兼容微控制器和LCD顯示控制器。進(jìn)行選擇時(shí)，應(yīng)考慮以下問題。

• LCD的工作電壓范圍是多少? 由于DS89C450是5V微控制器，其端口引腳工作在5V電平上，我們必須選擇一款5V LCD顯示板。注意，很多集成了LCD控制器的微控制器使用專用供電輸入(VLCD)來設(shè)置LCD控制器使用的電壓范圍。
• LCD的占空比是多少? 靜態(tài)LCD顯示板將顯示屏中的每一段連接至專用驅(qū)動(dòng)線。這意味著段驅(qū)動(dòng)器的數(shù)量必須等于被驅(qū)動(dòng)的LCD段的數(shù)量。然而，多路復(fù)用LCD顯示板的每一條段驅(qū)動(dòng)線(SEG)要驅(qū)動(dòng)一個(gè)以上的LCD段。這些顯示板使用多路公共背板(COM)輸出，根據(jù)所采用的占空比，驅(qū)動(dòng)SEG和COM線上VLCD和GND之間的多電平。由于我們使用的8051微控制器DS89C450只能將其端口引腳線驅(qū)動(dòng)到5V和GND，因此，我們的情況限于靜態(tài)LCD。關(guān)于驅(qū)動(dòng)多路復(fù)用LCD的詳細(xì)信息，請(qǐng)參考以下文檔：
  • 應(yīng)用筆記3548，"Using an LCD with MAXQ Microntrollers"。
  • MAXQ?系列用戶指南：MAXQ2000補(bǔ)充材料(English only)
• LCD顯示板工作需要多少段和多少公共驅(qū)動(dòng)器? 控制靜態(tài)LCD顯示板時(shí)，被驅(qū)動(dòng)的每一段需要一條驅(qū)動(dòng)線(端口引腳)，公共(COM)背板線需要額外的一個(gè)端口引腳。

對(duì)于本應(yīng)用筆記，選用了Lumex? LCD-S401C52TR顯示屏。該LCD是5V靜態(tài)顯示屏，含有4個(gè)7段數(shù)字和3個(gè)符號(hào)段(一個(gè)逗號(hào)和三個(gè)十進(jìn)制小數(shù)點(diǎn))。LCD上的每位數(shù)都由7段構(gòu)成，如圖1所示，A、B、G、E和D段被打開，顯示數(shù)字"2"。


圖1. 7段LCD顯示數(shù)字

LCD-S401C52TR顯示屏含有一個(gè)COM背板(連接至兩個(gè)引腳)和32個(gè)顯示段，每個(gè)都連接至段驅(qū)動(dòng)引腳。在這個(gè)例子中，我們只使用7段數(shù)字中的三個(gè)，意味著DS89C450需要驅(qū)動(dòng)21條SEG線(三個(gè)數(shù)位中的每一個(gè)需要7段)和一條COM線，從而共需要22個(gè)端口引腳。當(dāng)沒有采用擴(kuò)展存儲(chǔ)器總線配置工作時(shí)，DS89C450提供24個(gè)推拉端口引腳。因此，微控制器有足夠的I/O容量來完成這一任務(wù)(端口0還有其他的8個(gè)端口引腳。但是，三個(gè)引腳開漏，需要額外的上拉電阻才能用作通用I/O)。

硬件設(shè)置

這一例子的硬件設(shè)置基于DS89C450評(píng)估(EV)套件(B版)，去掉了存儲(chǔ)器接口CPLD (U5)和兩個(gè)外部存儲(chǔ)器芯片(U6和U7)。這一改動(dòng)釋放了多個(gè)端口引腳，可供我們的應(yīng)用程序使用，否則這些引腳可用于實(shí)現(xiàn)擴(kuò)展存儲(chǔ)器總線，特別是端口0 (所有8條線)、端口2 (所有8條線)、端口3.6和3.7。請(qǐng)參見表1 (注意：在這一例子中沒有使用端口0)。DS89C450含有64kB內(nèi)部代碼空間和1kB內(nèi)部數(shù)據(jù)SRAM，對(duì)于這一例子已經(jīng)足夠了。

LCD-S401C52TR顯示屏上的段和公共線通過靠近原型區(qū)的J4插頭連接至DS89C450的端口引腳。段行通過1kΩ電阻連接至端口引腳，而沒有直接和端口引腳連接。之所以采用這種設(shè)置是因?yàn)镈S89C450的端口引腳比LCD顯示板驅(qū)動(dòng)線常用的方式有更強(qiáng)的驅(qū)動(dòng)能力(0態(tài)和單穩(wěn)態(tài)強(qiáng)下拉，1態(tài)強(qiáng)上拉，然后弱上拉)。由于COM線有較大的電容，需要較強(qiáng)的驅(qū)動(dòng)，它直接連接到其端口引腳。但是，本應(yīng)用不建議段行直接由端口引腳驅(qū)動(dòng)。這種配置會(huì)出現(xiàn)一個(gè)問題：隨著越來越多的段打開，通過LCD顯示屏，在段和公共面之間的電容耦合會(huì)使COM線偏離其預(yù)置狀態(tài)(之所以出現(xiàn)這一問題，是因?yàn)楣ぷ鞫螌?duì)公共面總是保持正電壓)。結(jié)果，應(yīng)該關(guān)掉的段會(huì)被部分打開。所以通過電阻連接端口引腳，以減小驅(qū)動(dòng)能力，避免這一問題的發(fā)生。

表1. LCD顯示板和端口引腳連接

DS89C450 Port Pin	J4 Header Pin	LCD Pin(s)	LCD Signal	Notes
P1.0	1	21	4A	Through 1kΩ
P1.1	2	20	4B	Through 1kΩ
P1.2	3	19	4C	Through 1kΩ
P1.3	4	18	4D	Through 1kΩ
P1.4	5	17	4E	Through 1kΩ
P1.5	6	22	4F	Through 1kΩ
P1.6	7	23	4G	Through 1kΩ
P1.7	8	1, 40	COM	Connect directly
P2.0	21	25	3A	Through 1kΩ
P2.1	22	24	3B	Through 1kΩ
P2.2	23	15	3C	Through 1kΩ
P2.3	24	14	3D	Through 1kΩ
P2.4	25	13	3E	Through 1kΩ
P2.5	26	26	3F	Through 1kΩ
P2.6	27	27	3G	Through 1kΩ
P3.0	10	30	2A	Through 1kΩ
P3.1	11	29	2B	Through 1kΩ
P3.2	12	11	2C	Through 1kΩ
P3.3	13	10	2D	Through 1kΩ
P3.4	14	9	2E	Through 1kΩ
P3.5	15	31	2F	Through 1kΩ
P3.6	16	32	2G	Through 1kΩ

還需要對(duì)硬件設(shè)置進(jìn)行一些說明：

• 采用了一個(gè)標(biāo)準(zhǔn)16.384MHz晶振(插在Y1上)來為DS89C450提供時(shí)鐘。
• 運(yùn)行應(yīng)用程序時(shí)，DIP開關(guān)SW1.1和SW4.2應(yīng)在ON位置；所有其他應(yīng)為OFF。
• 裝入應(yīng)用程序(使用MAXQ微控制器工具套件(MTK)或者另一開發(fā)工具)時(shí)，DIP開關(guān)SW1.1、SW1.2、SW1.3、SW4.1和SW4.2應(yīng)在ON位置；所有其他應(yīng)為OFF。
• 當(dāng)LCD顯示屏運(yùn)行時(shí)，總是可以在LED條形顯示U10上看到端口1的狀態(tài)。這屬于正常，由于LCD顯示屏被緩沖過，因此，不會(huì)影響應(yīng)用程序。
• P3.0和P3.1也被用于串口0的Tx/Rx線。所以，當(dāng)應(yīng)用程序裝入(使用串口啟動(dòng)加載程序)時(shí)，由于這些線的活動(dòng)，LCD的一兩個(gè)段會(huì)閃爍。這屬于正常。當(dāng)應(yīng)用程序運(yùn)行時(shí)，DIP開關(guān)SW1.2和SW1.3應(yīng)關(guān)斷，以禁止串口功能。
• LCD顯示屏上任何沒有使用的段必須驅(qū)動(dòng)到OFF狀態(tài)，不允許浮空。可以通過將一個(gè)或者多個(gè)沒有使用的段連接至驅(qū)動(dòng)到OFF狀態(tài)(和COM相同的電壓波形)的端口引腳來完成這一任務(wù)，也可以將沒有使用的段直接連接至COM。

驅(qū)動(dòng)LCD段

LCD段的默認(rèn)狀態(tài)是OFF (例如，透明)；沒有加電壓時(shí)，段應(yīng)該為透明狀態(tài)，相對(duì)于LCD顯示板背景是看不到的。此外，當(dāng)相同的電壓加在段線(SEG)和公共背板(COM)上時(shí)，段保持關(guān)斷。當(dāng)段的SEG引腳和COM面之間有電壓差時(shí)，段才切換到ON (例如，不透明)狀態(tài)。當(dāng)該電壓達(dá)到一個(gè)特殊電平時(shí)，即閾值電壓，段變暗，最終完全不透明。閾值電壓是LCD顯示板指定工作電壓的百分比，不同的LCD有不同的閾值電壓。

電壓差的極性并不影響驅(qū)動(dòng)LCD段。例如，驅(qū)動(dòng)3V閾值電壓LCD的控制器可以通過設(shè)置COM至地，SEGn至3V來接通段n，也可以設(shè)置COM至3V，SEGn至地達(dá)到同樣目的。這一事實(shí)非常重要，因?yàn)槿绻鸏CD上的靜態(tài)直流電壓保持時(shí)間過長，段可能會(huì)被損害，無法再正常開關(guān)。為避免這一問題，不論段處于ON還是OFF狀態(tài)，總是以交替波形來驅(qū)動(dòng)LCD段，以確保每個(gè)段上總的直流電壓保持為零(圖2)。


圖2. 靜態(tài)LCD段的交替驅(qū)動(dòng)波形

如圖2所示，靜態(tài)顯示屏的COM引腳一直被一個(gè)50%占空比的方波驅(qū)動(dòng)，該方波電平在VLCD (我們的設(shè)置是5V)和GND之間。利用兩個(gè)模式之一來驅(qū)動(dòng)每一條段線。

• 要把段打到OFF，應(yīng)采用和我們驅(qū)動(dòng)COM引腳一樣的波形來驅(qū)動(dòng)它。這可以保證SEG/COM對(duì)上的直流電壓始終為零，意味著段將保持關(guān)斷。
• 要把段打到ON，應(yīng)采用和COM波形相反的信號(hào)來驅(qū)動(dòng)它。這意味著，一半的時(shí)間以正電壓驅(qū)動(dòng)段，另一半的時(shí)間以負(fù)電壓驅(qū)動(dòng)它。這兩個(gè)狀態(tài)有相同的視覺顯示，因此，段看起來一直接通。由于電壓差的平均直流值是零，不會(huì)有導(dǎo)致?lián)p害LCD玻璃的靜態(tài)直流偏置。

不同的LCD顯示板有不同的LCD驅(qū)動(dòng)頻率(稱之為幀頻率)。實(shí)際應(yīng)用合適的頻率值取決于特定硬件設(shè)置的試驗(yàn)情況。由于LCD段狀態(tài)改變率受限于段的總電容，LCD只在特定范圍的幀頻率內(nèi)才能正常工作。一般而言，這一范圍在20Hz至200Hz之間。本應(yīng)用筆記的實(shí)例代碼使LCD大概運(yùn)行在30Hz左右。特定顯示屏的幀速率太高或者太低都會(huì)導(dǎo)致LCD段閃爍，或者看起來變暗。

下面是驅(qū)動(dòng)LCD段運(yùn)行的主程序。

Main:
   mov    IE, #080h          ; Disable timer 0 interrupt temporarily
   mov    R2, DigitP1        ; Grab local copies of digit variables
   mov    R3, DigitP2
   mov    R4, DigitP3 
   mov    IE, #082h          ; Re-enable timer 0 interrupt

   mov    A, R2               
   call   getDigit           ; Calculate segment pattern for ones digit
   anl    A, #01111111b      ; Ensure that COM (P1.7) is driven low
   mov    P1, A

   mov    A, R3       
   call   getDigit           ; Calculate segment pattern for tens digit
   mov    P2, A

   mov    A, R4
   call   getDigit           ; Calculate segment pattern for hundreds digit
   mov    P3, A

;;;;  Delay loop  ;;;;

   mov    R0, #0FFh
L1A:
   mov    R1, #0FFh
L1B:
   djnz   R1, L1B
   djnz   R0, L1A

;;;;;;;;;;;;;;;;;;;;;;

   mov    A, R2               
   call   getDigit           ; Calculate segment pattern for ones digit
   cpl    A                  ; Inverse of the pattern driven on the first frame half
   orl    A, #10000000b      ; Ensure that COM (P1.7) is driven high
   mov    P1, A
 

   mov    A, R3
   call   getDigit           ; Calculate segment pattern for tens digit
   cpl    A                  ; Inverse of the pattern driven on the first frame half
   mov    P2, A

   mov    A, R4
   call   getDigit           ; Calculate segment pattern for hundreds digit
   cpl    A                  ; Inverse of the pattern driven on the first frame half
   mov    P3, A

;;;;  Delay loop  ;;;;

   mov    R0, #0FFh
L2A:
   mov    R1, #0FFh
L2B:
   djnz   R1, L2B
   djnz   R0, L2A

;;;;;;;;;;;;;;;;;;;;;;

   ljmp   Main               ; Go back for another frame cycle (endless loop)

注意，COM線(連接至P1.7)總是采用相同的波形驅(qū)動(dòng)：前半幀為低電平，后半幀為高電平。對(duì)于段線，幀第一部分的模式驅(qū)動(dòng)和第二部分的相反。以同樣方式將三個(gè)數(shù)位的每一個(gè)分別連接至三個(gè)端口之一，所以，段A總是連接至Px.0，段B連接至Px.1，依此類推。這種配置使實(shí)例代碼能夠使用getDigit子程序來計(jì)算三個(gè)LCD顯示板數(shù)位中每一個(gè)的段模式。

;***************************************************************************
;*
;*  getDigit
;*  
;*  Returns an LCD segment pattern (in Acc) for the decimal digit (0 to 9)
;*  input (also in Acc)
;*

getDigit:
   cjne   A, #0, getDigit_not0
;             xgfedcba
   mov    A, #00111111b         ; Zero
   ret
getDigit_not0:
   cjne   A, #1, getDigit_not1
;             xgfedcba
   mov    A, #00000110b         ; One
   ret
getDigit_not1:
   cjne   A, #2, getDigit_not2
;             xgfedcba
   mov    A, #01011011b         ; Two
   ret
getDigit_not2:
   cjne   A, #3, getDigit_not3
;             xgfedcba
   mov    A, #01001111b         ; Three
   ret

getDigit_not3:
   cjne   A, #4, getDigit_not4
;             xgfedcba
   mov    A, #01100110b         ; Four
   ret
getDigit_not4:
   cjne   A, #5, getDigit_not5
;             xgfedcba
   mov    A, #01101101b         ; Five
   ret
getDigit_not5:
   cjne   A, #6, getDigit_not6
;             xgfedcba
   mov    A, #01111101b         ; Six
   ret
getDigit_not6:
   cjne   A, #7, getDigit_not7
;             xgfedcba
   mov    A, #00000111b         ; Seven
   ret
getDigit_not7:
   cjne   A, #8, getDigit_not8
;             xgfedcba
   mov    A, #01111111b         ; Eight
   ret
getDigit_not8:
   cjne   A, #9, getDigit_not9
;             xgfedcba
   mov    A, #01101111b         ; Nine
   ret
getDigit_not9:
   mov    A, #0
   ret   

運(yùn)行計(jì)數(shù)器

實(shí)例代碼中LCD上顯示的模式是3位十進(jìn)制計(jì)數(shù)器，上電時(shí)從000開始，遞增至001，002，直到999，然后翻轉(zhuǎn)。由于程序的主循環(huán)驅(qū)動(dòng)LCD段和公共模式，我們必須找到另一方法來周期性地遞增計(jì)數(shù)器值。我們的方案是使用定時(shí)器0來周期性地觸發(fā)中斷。

   mov    TMOD, #021h        ; Timer 1: 8-bit autoreload from TH1
                             ; Timer 0: 16-bit
   mov    TCON, #050h        ; Enable timers 0 and 1
   mov    CKMOD, #038h       ; Use system clock for all timer inputs

   mov    IE, #082h          ; Enable timer 0 interrupt

每次發(fā)生定時(shí)器中斷時(shí)，寄存器中的延時(shí)計(jì)數(shù)器被遞減。當(dāng)延時(shí)計(jì)數(shù)器達(dá)到零時(shí)，LCD 3位計(jì)數(shù)器值遞增1 (根據(jù)需要，每一數(shù)位翻轉(zhuǎn))；延時(shí)計(jì)數(shù)器初始化到其最大值。由于定時(shí)器0寬度是16位，實(shí)例代碼將延時(shí)計(jì)數(shù)器設(shè)置為20，3位計(jì)數(shù)器大概每(1/16.384MHz) × (216) × 20 = 0.08s ，即每秒12次，遞增一次。

   org     000Bh             ; Timer 0 interrupt
   ljmp    IntTimer0


;***************************************************************************
;*
;*  IntTimer0 (INTT0)
;*  
;*  Timer interrupt service routine
;*

IntTimer0:
   push    ACC               ; Save off accumulator and R0
   push    R00

   mov     R0, Count         ; Only increment LCD digits every [CountMax]
                             ; interrupt cycles
   djnz    R0, INTT0_Done 
   
   inc     DigitP1           ; Increment ones digit on display
   mov     A, DigitP1
   cjne    A, #10, INTT0_Continue      ; Check for rollover

   mov     DigitP1, #0
   inc     DigitP2           ; Increment tens digit on display
   mov     A, DigitP2
   cjne    A, #10, INTT0_Continue      ; Check for rollover

   mov     DigitP2, #0
   inc     DigitP3           ; Increment hundreds digit on display
   mov     A, DigitP3
   cjne    A, #10, INTT0_Continue      ; Check for rollover

   mov     DigitP3, #0

INTT0_Continue:
   mov     R0, CountMax      ; Reset to starting cycle count
INTT0_Done:
   mov     Count, R0         ; Update cycle counter
   pop     R00
   pop     ACC               ; Restore accumulator and R0
   reti

結(jié)論

利用微控制器的大量專用數(shù)字外設(shè)，可以根據(jù)需要在軟件中實(shí)現(xiàn)靜態(tài)或者多路復(fù)用LCD顯示屏控制器。簡單的靜態(tài)顯示使這一實(shí)現(xiàn)非常直觀。DS89C450等8051微控制器的標(biāo)準(zhǔn)通用I/O功能可以用于驅(qū)動(dòng)LCD上的SEG和COM波形。使用高性能DS89C450，即使在軟件中實(shí)現(xiàn)LCD控制器，也可以保證主應(yīng)用程序有足夠的處理能力。